SAS PROGRAMMING
                                           HANDOUT #16

       This handout illustrates some extra features of the PUT statement.
       More examples an be from on the webpage for SAS PROGRAMMING II, taught Summer 1999-2000, handouts 12-16

DATA TRANSACT;
 LENGTH COMP  $10.;
 INPUT NAME $ EMPL_ID @17 DATE DATE7. @28 COMP $10. @38 COMP_ID ITEM_ID $ UNITS;
CARDS;
FOSTER   546    23FEB95    ABC INC     326   P02   3
FOSTER   546    19FEB95    INFO INC    153   M33   2
FOSTER   546    03MAR95    INFO INC    153   M33   2
FOSTER   546    26JAN95    INFO INC    153   S03   2
FOSTER   546    11FEB95    INFO INC    153   S03   1
GRANT    258    19JAN95    MACRO INC   134   D11   5
GRANT    258    09FEB95    MACRO INC   134   D11   2
GRANT    258    09FEB95    MICRO INC   132   C32   1
GRANT    258    05MAR95    MICRO INC   132   S03   4
GRANT    258    12JAN95    MICRO INC   132   V02   11
GRANT    258    09FEB95    MICRO INC   132   V02   1
GRANT    258    13FEB95    MOD INC     345   M33   1
GRANT    258    12FEB95    NEW INC     330   C32   2
GRANT    258    18FEB95    NEW INC     330   Z01   2
GRANT    258    03MAR95    TECH INC    043   C32   1
GRANT    258    02FEB95    TECH INC    043   D34   25
GRANT    258    11FEB95    TECH INC    043   D34   5
GRANT    258    03MAR95    TECH INC    043   Z01   2
FOSTER   546    20FEB95    XYZ INC     320   C32   6
;
DATA _NULL_;                     *no data set is created, save time and space;
 SET TRANSACT;
 FILE PRINT NOTITLES;
 PUT 'SALE:' @7 NAME $10. @20 DATE DATE7. @31 COMP $10. @48 ITEM_ID @53 UNITS;
RUN;
DATA _NULL_;                       *example of    -c for centering;
 SET TRANSACT;
 FILE PRINT NOTITLES;
 PUT 'SALE:' @7 NAME $10. @20 DATE DATE7. @31 COMP $10. -c @48 ITEM_ID @53 UNITS ;
RUN;
DATA _NULL_;                       *example of  -r  for right justify;
 SET TRANSACT;
 FILE PRINT NOTITLES;
 PUT 'SALE:' @7 NAME $10. @20 DATE DATE7. @31 COMP $10. -r @48 ITEM_ID @53 UNITS ;
RUN;
DATA _NULL_;                       *example of   +5   and   2.;
 SET TRANSACT;
 FILE PRINT NOTITLES;
 PUT 'SALE:' @7 NAME $10. @20 DATE DATE7. @31 COMP $10. +5 ITEM_ID @53 UNITS 2.;
RUN;
DATA _NULL_;                       *example of   /  line advance;
 SET TRANSACT;
 FILE PRINT NOTITLES;
 PUT 'SALE:' @7 NAME $10. @20 DATE DATE7. // @31 COMP $10. +5 ITEM_ID @53 UNITS 2.;
RUN;

DATA _NULL_;                        *create headers;
 SET TRANSACT;
 FILE PRINT NOTITLES header=pagetop;
 PUT   @7 NAME $10. @22 DATE DATE7. @34 COMP $11. @52 ITEM_ID @61 UNITS 2.;
 return;
 pagetop:                                   *notice this is a colon;
  put @23 'Lake Systems. Incorporated' /
      @18 'Detailed Listing of Sales Tranactions' /
      @6  59*'_';
  put @6 'Name of Sales'  @23 'Sale' @35 'Company' @51 'Item' @60 'Units' /
      @6 'Representative' @23 'Date' @36 'Name' @51 'Sold' @60 'Sold' //;
 return;
RUN;