*hand20.txt;

DATA SALES;
 LENGTH ITEM $12;
 INPUT NAME $ MONTH WEEKDAY COMPID STATE $ @25 ITEM   $ & UNITS RETAIL TOTRET;
CARDS;
FOSTER   1  2  153  ID  SYSTEM         2    3100   6200
FOSTER   1  4  333  WY  Z-80           4    26     104
FOSTER   1  5  326  MT  SOFTWARE       1    99     99
FOSTER   1  6  320  NV  CABLE          3    20     60
FOSTER   2  3  333  WY  SOFTWARE       2    99     198
FOSTER   2  4  153  ID  SYSTEM         1    3100   3100
FOSTER   3  2  333  WY  Z-80           3    26     78
FOSTER   3  3  153  ID  MODEM          2    200    400
FOSTER   3  6  320  NV  CABLE          6    20     120
GRANT    1  2  043  OR  DISKS          25   5      125
GRANT    1  2  132  CA  VDT            11   199    2189
GRANT    1  2  134  CA  DISK DRIVE     5    350    1750
GRANT    2  2  132  CA  VDT            1    199    199
GRANT    2  2  134  CA  DISK DRIVE     2    350    700
GRANT    2  4  043  OR  DISKS          5    5      25
GRANT    2  4  330  WA  Z-80           2    26     52
GRANT    2  6  345  CA  MODEM          1    200    200
GRANT    3  3  043  OR  Z-80           2    26     52
GRANT    3  5  132  CA  SYSTEM         4    3100   12400
GRANT    3  5  330  WA  CABLE          2    20     40
;
OPTIONS NODATE LS=65 NONUMBER;
PROC FORMAT;
  VALUE MONFMT 1='JANUARY '
               2='FEBRUARY'
               3='MARCH   ';          *same length;
PROC FORMAT;
 PICTURE PCTFMT(ROUND)LOW-HIGH='    009.9%';

PROC TABULATE FORMAT=8.  ;                              *total percentages;
 CLASS NAME MONTH;
 VAR UNITS;
 FORMAT MONTH MONFMT.;
 TABLE MONTH*(N PCTN*F=PCTFMT.), NAME/rts=25;
 LABEL MONTH='MONTH OF SALE';
 TITLE1 'Percentage of Total Sales Generated by';
 TITLE2 'Each Sales Representative in Each Month';
run;

PROC TABULATE FORMAT=8.  ;                              *column percentages;
 CLASS NAME MONTH;
 VAR UNITS;
 FORMAT MONTH MONFMT.;
 TABLE MONTH, NAME*UNITS*SUM
              NAME*UNITS*PCTSUM<MONTH>*F=PCTFMT. /RTS=25;
 LABEL MONTH='MONTH OF SALE';
 TITLE1 "Percentage of Sales Representatives's Revenue";
 TITLE2 'Generated Each Month';
run;

PROC TABULATE FORMAT=8.  ;                              *row percentages;
 CLASS NAME MONTH;
 VAR TOTRET;
 FORMAT MONTH MONFMT.;
 TABLE MONTH*TOTRET*(SUM PCTSUM<NAME>*F=PCTFMT.), NAME /RTS=25;
 LABEL MONTH='MONTH OF SALE';
 TITLE1 "Percentage of Each Month's Revenue";
 TITLE2 'Generated by Each Sales Representative';
run;

PROC TABULATE FORMAT=8.  ;                              *totals;
 CLASS NAME MONTH;
 VAR TOTRET;
 FORMAT MONTH MONFMT.;
 TABLE (MONTH ALL)*TOTRET*(SUM PCTSUM<NAME ALL>*F=PCTFMT.), NAME ALL /RTS=25;
 LABEL MONTH='MONTH OF SALE';
 TITLE1 "Percentage of Each Month's Revenue";
 TITLE2 'Generated by Each Sales Representative';
run;


PROC TABULATE FORMAT=8.  ;                              *total percentages;
 CLASS NAME MONTH STATE ITEM;
 VAR UNITS;
 FORMAT MONTH MONFMT.;
 TABLE MONTH*ITEM*(N PCTN*F=PCTFMT.), NAME*STATE/rts=25;
 WHERE MONTH IN (1) & STATE IN ('CA','OR')  ;
 TITLE1 'Percentage of Total Sales Generated by';
 TITLE2 'Each Sales Representative in Each Month';
run;